如果您是在精華區瀏覽本文，可以按後列連結至討論區的同文，以觀看最新的版本：http://forum.gamer.com.tw/C.php?bsn=05219&snA=372543
或者至小弟的論壇查看最新的更新：http://horde.guinie.org/thread-296-1-1.html
此外，希望各種對於巨集的提問，以及「求某某巨集」等，可統一在本文以回覆方式提出，以避免版面被大量提問文佔用，也能讓此文保持在大家都看得到的地方（依巴哈姆特的設定，無法分區置頂，置頂文已經夠多了，巨集區不便再向板主要求佔用一欄），同時也能讓此文不至於因為沉沒而被系統自動刪除。
提問時請注意：
一、詳細描述您使用的問題，包含錯誤訊息、在哪種狀況下使用等等。
二、提問時請貼出「您修改後的巨集」，而非巨集樣本內原本的巨集。
請善用瀏覽器的搜尋功能尋找您需要的巨集，
IE、火狐、Opera、Google瀏覽器的預設快捷鍵皆為「Ctrl+F」。
相關連結
- 致本板發問者：巨集的基本功能與限制（附常見問題解說）
- 巨集對象單位、條件一覽
- 巨集通用參數一覽
- 偽．連結，我有[正妹]成就！
- 3.2.2臺版本地化指令一覽
- 3.3.0巨集相關更動及新功能解釋、範例
- 3.3.0指令變動
索引
- 第一篇：索引；前言；基本巨集
- 第二篇：一般通用巨集；治療通用巨集
- 第三篇：特殊、罕用、雜項巨集；首領戰跑位示意圖
- 第四篇：職業專用巨集
更新
- 981208：雜項區加入「查詢坐騎欄位編號」。
- 981203：雜項區加入「錯誤訊息、錯誤音效相關巨集」。
- 981201：雜項區加入「隨機坐騎腳本修改版」。
- 981124：雜項區加入「技能通報」。
- 981106：修正職業區（獵人）「餵食寵物、復活寵物、召喚寵物、治療寵物合一」此巨集的錯誤。增加職業區（戰士）「一鍵換盾，施放法術反射、盾牆」的內容。
- 981102：雜項區加入「冬握湖開戰時間通報」。
- 981028：基本區加入「依目標友好度施放技能」。
- 980920：職業區（獵人）加入「餵食寵物、復活寵物、召喚寵物、治療寵物合一」。
- 980911：職業區（戰士）加入「換狂姿、拳擊斷法」。
- 980904：職業區（戰士）加入「換盾、盾擊斷法」。
- 980902：基本區加入「依天賦施放不同技能」、「雙天賦切換」。簡化巨集顏色設定……
- 980728：職業區（聖騎士）加入「犧牲」。
- 980629：雜項區加入「奧杜亞攻城區石毀車乘客三合一巨集」。
- 980421：雜項區加入「在巨集內貼入物品連結、技能連結、天賦連結、成就連結等」。
- 980420：基本區加入「依輔助鍵與滑鼠按鍵施放不同技能」。
- 980403：基本區加入「對物品使用技能」。雜項區加入「隨機喊話」。 職業區（盜賊）加入「一鍵塗毒」。
- 980328：雜項區加入「喊話帶目標圖示」。
- 980326：職業區（聖騎士）加入「聖盾爐石」。一般通用區加入「通用對敵施放」。
- 980324：職業區（死亡騎士）加入「永恆之眼抓力量火花」。特殊區加入「尋找稀有怪物」。
- 980323：巨集代碼部份上色，方便識別，免得有人傻傻連同註解直接複製。（靠，好累……）
- 980311：開首領戰區，加入跳舞王跑位示意圖。
- 980306：職業區（聖騎士）加入「祝福合一」。
- 980303：基本區加入「依姿態施放不同技能」。
- 980301：基本區加入「對特定對象施放技能」。
- 980226：職業區（戰士）加入「熱血沸騰觸發猛擊」。
- 980223：職業區（獵人）加入「強化追蹤」。
- 980217：基本區加入「依滑鼠按鍵施放不同技能」。
前言
閱讀本文前，可先參考本人另一篇文章《巨集的基本功能與限制》。本文收錄了一些常用或不常用的巨集樣本，部份自己撰寫，部份自網路上取用。便於不願學習、不能學習、不屑學習、不想學習巨集的板友直接修改。若板友有補充、建議、指正、提問，亦可直接於此發表回覆。
為節省版面，本處巨集若無另行標示，皆應自行在首行添加「#showtooltip」以顯示技能或物品提示。關於「#showtooltip」的功能，可參閱《巨集的基本功能與限制》第二篇。
本文許多範例皆包含「mouseover」滑鼠對象單位，可能不符合部份板友的使用習慣，可嘗試適應或自行修改。
本文隨時可能增刪或修改。
本文格式
本文以刪節號「……」表示重複或可無限增加的內容；以兩個問號「？？」代表可任意代入的內容。大寫「N」通常代表任意數或無限大數。
- 淺藍色背景代表巨集內容。
- 紫色背景代表腳本。
- 灰色背景代表重複或可無限增加的內容。
- 紅色文字代表必須自行修改的內容。
基本
此部份為基本範例，各項範例多半可以自行拼湊、組合、應用。
980216：施放技能並喊話
/施放 技能名稱
/y 喊話內容
其中「y」為大喊，可以替換成你要喊話的頻道，如「p」隊伍、「g」公會、「ra」團隊、「rw」團隊警告等等。可加入相關內建變數：「%T」為目標的名字，「%F」為專注目標的名字。比如：「/y 我要對%T開怪囉！」
980216：喊話排程
/in 1 /y 喊話內容
/in 2 /y 喊話內容
……
/in N /y 喊話內容
數字為等待秒數，代表按下巨集N秒後。通常應用於開怪、進門或開始戰鬥之倒數。其中「y」為大喊，與前條相同。「/in」指令需要Ace函式庫支援。
980216：同時施放
/施放 技能名稱
/施放 技能名稱
……
/施放 技能名稱
僅能作用於不互卡冷卻時間的技能。此包含公用冷卻時間。
980216：施放同時使用物品
/使用 物品名稱
/使用 物品名稱
……
/使用 物品名稱
/施放 技能名稱
與前一條相同，僅能作用於不互卡冷卻時間的技能或物品。
980216：循環施放
/連續施法 reset=N/target/combat/shift/alt/ctrl 技能名稱,技能名稱,……技能名稱
「N」可替換為數字，代表秒數，即後N秒後重置順序（以最近一次使用該巨集開始算），從第一招開始施放。「target」為選取（或更換）目標後重置；「combat」為戰鬥後重置；「shift」、「alt」、「ctrl」則為以這些輔助鍵啟動巨集時重置，可自行取捨，將不需要的條件刪去即可。
980216：戰鬥中施放不同技能
/施放 [combat]戰鬥中技能名稱;非戰鬥中技能名稱
通常用於防職開怪。比如「戰鬥中技能名稱」可以填入「衝鋒」，「非戰鬥中技能名稱」可以填入「英勇打擊」。以前版本也常在非戰鬥中以一級技能省魔抓潛行，現今技能消耗標準化，此法已不可行。
980216：依輔助鍵施放不同技能
/施放 [modifier:shift]Shift技能名稱;[modifier:alt]Alt技能名稱;[modifier:ctrl]Ctrl技能名稱;無輔助鍵時技能名稱
單純給沒裝動作條插件的玩家省格子及縮短手指移動距離。
980217：依滑鼠按鍵施放不同技能
/施放 [button:2]右鍵技能名稱;[button:3]中鍵技能名稱;一般技能名稱（左鍵或其他鍵）
與前項差不多，單純省格子。
感謝板友jack3107提供。（原文5樓）
980420：依輔助鍵與滑鼠按鍵施放不同技能。
/施放 [mod:alt,btn:2]技能一;[mod:alt]技能二;[mod:ctrl,btn:2]技能三;[mod:ctrl]技能四;[mod:shift,btn:2]技能五;[mod:shift]技能六;[btn:2]技能七;技能八
- 技能一：ALT+右擊
- 技能二：ALT+一般（指滑鼠左鍵或鍵盤快捷鍵）
- 技能三：CTRL+右擊
- 技能四：CTRL+一般（指滑鼠左鍵或鍵盤快捷鍵）
- 技能五：SHIFT+右擊
- 技能六：SHIFT+一般（指滑鼠左鍵或鍵盤快捷鍵）
- 技能七：右擊
- 技能八：一般（指滑鼠左鍵或鍵盤快捷鍵）
簡單講就是一個格子塞八種技能，建議拿來整合不常用的技能，畢竟常用技能這種放法不甚便捷。加入「bnt:3」的話還能配合滑鼠中鍵，整合十二種技能，如果滑鼠有特殊鍵（如羅技、微軟的高級鼠多半提供二個至多個特殊鍵），甚至能配合「bnt:4」、「bnt:5」等加入更多的技能。前提是你255個字裝得下。
980301：對特定對象施放技能
/施放 [target=UNIT]技能名稱
修改其中「UNIT」即可改變目標。
- target：目前目標。
- mouseover：游標對象。
- focus：專注目標。
- player：自身。
- pet：寵物。
- party1～party4：隊友。
- partypet1～partypet4：隊友寵物。
- raid1～raid40：團員。
- raidpet1～raidpet40：團員寵物。
- 單位姓名：直接輸入單位的姓名，如希瓦那斯、索爾等。
980303：依姿態施放不同技能
/施放 [stance:1]技能名稱;[stance:2]技能名稱;……[stance:N]技能名稱
修改數字以表示不同的姿態。
若職業全姿態已學滿，則數字代表：
| 德魯伊 | 戰士 | 薩滿 | 盜賊 | 牧師 | |
| [stance:1] | 熊 | 戰鬥 | 鬼魂之狼 | 潛行 | 暗影 |
| [stance:2] | 水棲 | 防禦 | |||
| [stance:3] | 獵豹（貓） | 狂暴 | |||
| [stance:4] | 旅行 | ||||
| [stance:5] | 樹、鳥 | ||||
| [stance:6] | 飛行 |
980403：對物品使用技能
/施放 技能名稱
/使用 物品名稱
多半應用在獵人的餵食寵物、珠寶學的爆礦、附魔的拆解等等。
980902：依天賦施放不同技能
/施放 [spec:1]主天賦技能名稱;副天賦技能名稱
或
/施放 [spec:2]副天賦技能名稱;主天賦技能名稱
或
/施放 [spec:1]主天賦技能名稱;[spec:2]副天賦技能名稱
980902：雙天賦切換
/usetalents [spec:1]2; [spec:2]1
使用主天賦時切換為副天賦，使用副天賦時切換為主天賦。另外，有哪位知道這指令的中文版本嗎……（補：已查。中文指令為「/啟用天賦」。）
981028：依目標友好度施放技能
/施放 [harm]技能一;技能二
如目標為敵對，則施放技能一，否則施放技能二。
/施放 [help]技能一;技能二
如目標為友好，則施放技能一，否則施放技能二。
此二項功能相同，判斷方式相反而已，可自行選用。不填「技能二」則只在符合狀況時施放技能一。
一般通用
一般可供全職業或數個職業應用的巨集。
980216：設定專注目標並施放技能
/專注目標 [target=focus,noexists][target=focus,dead][modifier:alt]target
/施放 [target=focus,exists][]技能名稱
若專注目標不存在或死亡，或以「Alt」啟動巨集，則設目前目標為專注目標。
若專注目標存在，對專注目標施放技能。否則以一般方式施放技能。
多用於控場職監控、補控場。其中「alt」可更改為「ctrl」或「shift」等。
980216：萬用遠程攻擊
/施放 [equipped:遠程武器/魔杖,target=mouseover,harm][equipped:遠程武器/魔杖]射擊;[equipped:投擲武器,target=mouseover,harm][]投擲
自動判定目前裝備該用射擊還是投擲，簡單說就是換裝免換快捷列。
980326：通用對敵施放
/施放 [target=mouseover,harm][target=mouseovertarget,harm][harm][target=targettarget,harm]技能名稱
如果游標對象為敵對，則對游標對象施放技能。
否則，如果游標對象的目標為敵對，則對游標對象的目標施放技能。
否則，若目標為敵對，則對目標施放技能。
否則，若目標的目標為敵對，則對目標的目標施放技能。
可以點著坦直接打坦在打的怪，也可以一邊打目前目標，一邊用游標對其他對象，或者其他對象的目標放技能，很方便。
治療通用
此部份能使用的技能有局限性，多以治療技能為主。
980216：通用便捷治療巨集
/施放 [target=mouseover,help,nodead][help][target=targettarget,help][target=player]技能名稱
游標對象為友方，則對游標對象施放技能；（游標移到隊友人物、隊伍大頭或團隊框架上就能補，省下點選目標的時間。）
不符前項，且目前目標為友方，則對目前目標施放技能；（一般治療。）
不符前項，且目前目標的目標為友方，則對目標的目標施放技能；（打特定首領時可以無腦刷首領的目標。）
不符前項，則對自身施放技能。
簡單說，有游標對象就對游標對象施放，沒游標對象就對目標施放，無法對目標施放則對目標的目標施放，無法對目標的目標施放則對自己施放。適用於所有治療、驅散、輔助技能。
980216：自動判定可補可打的技能
/施放 [target=mouseover,help,nodead,group][help,group][target=targettarget,help,group][target=mouseover,exists,nodead][]技能名稱
游標對象為友方，且自身在隊伍或團隊裡，則對游標對象施放技能。
不符前項，且目標為友方，且自身在隊伍或團隊裡，則對目標施放技能。
不符前項，且目標的目標為友方，且自身在隊伍或團隊裡，則對目標的目標施放技能。
不符前項，且游標對象存在，則對游標對象施放技能。
不符前項，則依照一般方式施放技能。
此巨集應用在可傷害敵方亦可治療友方的技能，如牧師的懺悟、聖騎士的神聖震擊。簡而言之，在隊伍裡時限制該技能只能拿來補，以免誤中敵人而浪費法力，而單練時可拿來做傷害。
罕用或特殊場合用，以及其他雜項巨集
本處收錄一些比較少用的，或者難以分類的巨集。所有用到「SendChatMessage」函式的腳本，其「發送頻道」處，都可以替換為：- SAY：說
- EMOTE：表情
- PARTY：小隊
- BATTLEGROUND：戰場
- GUILD：公會
- OFFICER：幹部
- YELL：大喊
- RAID：團隊
- RAID_WARNING：團隊警告
980216：目標血量通報
/關閉巨集 [noexists]
/跑 h=UnitHealth('target');hm=UnitHealthMax('target');hp=floor(100*(h/hm));SendChatMessage("%T 生命："..h.."/"..hm.."（"..hp.."％）","YELL")
其中YELL為大喊，可替換為其他頻道。
980216：請求治療
/跑 n=UnitName('player');h=UnitHealth('player');hm=UnitHealthMax('player');hp=floor(100*(h/hm));lh=h-hm;SendChatMessage(n.."生命危急："..h.."/"..hm.." "..hp.."％（"..lh.."）請求治療！","YELL")
通報自身血量並求援，前項修改應用。
980216：降血（消除增益）
/取消光環 命令之吼
/取消光環 堅韌禱言
/取消光環 真言術:韌
近戰職打縫補者用。後面可自行加入你所能想得到恢復生命的增益，比如戰士可加入嗜血，或者把德魯依、牧師的持續治療狀態給加進去。當然，對於經驗豐富的農團，近戰就算滿血去打也不會有危險，但對拓荒團或野團還是相當有用。（目前縫補者已改為依仇恨判斷憎恨打擊對象，無必要降血，可自行修改增益名稱以適用其餘需要手動取消增益之情況。）
980216：隨機坐騎
/使用隨機 [mod:ctrl]愛用地面坐騎名稱;[mod:alt]愛用空中坐騎名稱;[noflyable][button:2]地面坐騎名稱,……地面坐騎名稱;空中坐騎名稱,……空中坐騎名稱
/下馬 [mounted]
Ctrl召喚愛用地面坐騎；Alt召喚愛用空中坐騎；右鍵隨機召喚地面坐騎；左鍵依目前區域是否允許飛行，隨機召喚空中或地面坐騎。
若目前騎乘中則解除坐騎。
980324：尋找稀有怪物
/目標 瘋狂的因度雷生還者
/目標 土克瑪斯
/目標 血色大領主黛伊昂
/目標 祖爾德拉克哨兵
/目標 格里根
/目標 德碁
/目標 大族長裘弗斯
/目標 古老的普崔達斯
/目標 希爾達娜·亡據者
/目標 沸騰憎恨
/目標 葛洛克拉
/目標 『雕骨者』塞瑞安
/目標 乒乒王
/目標 『戰爭侍女』葳格迪斯
/目標 『嗜血者』佩洛巴斯
/目標 冰角
/目標 方寶·機風
/目標 老晶樹
/目標 奧托納
/目標 克洛許王
/目標 羅奎納哈克
感謝板友wolfjofei提供，原文：http://forum.gamer.com.tw/C.php?bsn=05219&snA=381147
980328：喊話帶目標圖示
/跑 x,i={"{星星}","{圈圈}","{鑽石}","{三角}","{月亮}","{方形}","{十字}","{頭顱}"},GetRaidTargetIndex("target")if(i)then x=x[i]else x=""end;SendChatMessage("文字"..x..x.."%T"..x..x.."文字","YELL")
喊話中的「x」即為圖標，沒標者不會顯示。「%T」為目標名字。兩個「文字」可自行修改為想要的內容。「YELL」為大喊，可修改為其他頻道。
980403：隨機喊話
/跑 local s={"發話1","發話2","發話N"} SendChatMessage(s[random(1,#s)],"YELL")
發話以半形雙引號包住，每個發話間以半形逗號隔開，基本上想寫幾個就寫幾個，不要超過255字元即可。然後注意修改的時候不要誤刪那個半形雙引號「""」……
YELL為大喊，可修改為其他頻道。
980421：在巨集內貼入物品連結、技能連結、天賦連結、成就連結等
用GUI介面創建的巨集，是無法含有物品或技能連結的（倒是可以貼專業技能連結），可以考慮用腳本創建一個含有連結的巨集，再用GUI介面修改。
在聊天框輸入：
/跑 CreateMacro("巨集名稱",0,"巨集內容",0,0)
其中巨集名稱可以隨意，巨集內容部份則使用一般方法貼入技能連結，第二個「0」（黃標部份），是指帳號共用巨集，若修改為「1」，則為角色專用巨集。其他部份則不需修改。（第一個「0」為巨集圖示，可以事後用GUI介面修改，最後一個「0」……好吧，說真的，我忘了。囧）
確認輸入無誤之後，按下「Enter」就像一般發話的方式送出，如果沒有報錯，代表成功。之後再打開巨集介面，找到你剛剛輸入的巨集名稱，然後作其他編輯，比如加入其他文字、修改巨集名稱或圖示等。
用這種方法需要注意的是，貼入巨集的連結文字雖然只有短短幾個字，而GUI介面也是顯示短短幾個字，但實際儲存時會變成「|cff71d5ff|Hspell:60119|h[黑色戰熊]|h|r」這類東西，即便GUI介面顯示未超過255字，但實際上已經遠遠超過，退出遊戲後重新進入，就會被截斷，因此應自行斟酌文字數量。
980629：奧杜亞攻城區石毀車乘客三合一巨集
/施放 迫擊砲
/施放 防空火箭
/施放 [target=mouseover,noharm][noharm]取得彈藥箱
功能一、迫擊砲、防空火箭無腦亂射。
功能二、直接以游標對象抓取黃鐵罐。
981102：冬握湖開戰時間通報
/跑 local g=GetWintergraspWaitTime() if(g)then local m,s=floor(g/60),g%60 SendChatMessage("冬握湖開戰時間剩餘："..m.."分"..s.."秒","YELL")end
/跑 local g=GetWintergraspWaitTime() if(g)then local m,s=floor(g/60),g%60 print("冬握湖開戰時間剩餘："..m.."分"..s.."秒")end
前者的通報至頻道，後者顯示在自己的聊天視窗內。
981124：技能通報
/跑 F=F or CreateFrame("frame");F:RegisterEvent("UNIT_SPELLCAST_SENT")F:SetScript("OnEvent",function()if arg1=="player" and arg2=="技能名稱" then SendChatMessage("喊話內容","YELL")F:SetScript("OnEvent",nil)end end)
/施放 技能名稱
這個大家貼來貼去，也不知道原始出處是哪了，總之就是註冊了「UNIT_SPELLCAST_SENT」此一事件，判斷技能施放是否成功，成功後才喊話。
本來是不想收在這，坦白說對在巨集內使用腳本註冊事件挺反感的，況且使用CastYeller2之類的插件可以達到更好的效果，不過由於最近板上很多問題都是對此而發，也就乾脆收了……
981201：隨機坐騎腳本修改版
/下馬
/離開載具
/跑 local t=GetZoneText()if(((t=="達拉然")and(GetSubZoneText()~="卡薩斯平臺"))or((t=="冬握湖")and(not GetWintergraspWaitTime()))or not IsFlyableArea())then t={地1欄位,地2欄位,……地n欄位}else t={空1欄位,空2欄位,……空n欄位}end CallCompanion("MOUNT",t[random(#t)])
自動判定所在區域是否能飛行，除了一般區域判定外，另外包含達拉然的卡薩斯平臺，以及在冬握湖內時，判斷是否開戰。
紅字部份輸入坐騎欄位，欄位編號請打開坐騎頁面：
第一頁第一列為：1、2、3、4、5、6，第二列為7、8、9、10、11、12，第二頁第一列為13、14、15、16、17、18，第二列為19、20、21、22、23、24，依此類推。
若嫌計算欄位麻煩，或可參見「981208：查詢坐騎欄位編號」腳本。
原文：http://forum.gamer.com.tw/Co.php?bsn=05219&sn=4083185
981203：錯誤訊息、錯誤音效相關巨集
關閉錯誤音效：/控制臺 Sound_EnableSFX 0
啟動錯誤音效：/控制臺 Sound_EnableSFX 1
隱藏錯誤訊息：/跑 UIErrorsFrame:Hide()
清除錯誤訊息：/跑 UIErrorsFrame:Clear()
顯示錯誤訊息：/跑 UIErrorsFrame:Show()
很多無腦連按巨集，都會被錯誤訊息或錯誤音效洗爽爽。只要在巨集最前面加入關閉錯誤音效的指令，並在最後一行啟動錯誤音效，就可以忽略巨集運行中所產生的任何錯誤音效，如「怒氣不足」、「太遠了」之類，而不影響非此巨集造成的錯誤音效。
錯誤訊息部份，只要在最後一行加入清除錯誤訊息的指令即可，但有時狂按之下還是會顯示出來，可以在巨集最前面加入隱藏錯誤訊息，然後最後面加入清除和顯示。
981208：查詢坐騎欄位編號
/跑 for i=1,GetNumCompanions("MOUNT")do local _,creatureName,_,_,_=GetCompanionInfo("MOUNT", i)print(i.."："..creatureName)end
由於「981201：隨機坐騎腳本修改版」此一腳本，必須自己計算坐騎欄位編號，十分麻煩，因此寫了個查詢編號的腳本與之配合，直接把前列腳本貼入巨集或輸入聊天即可查詢所有坐騎的欄位編號。
首領戰跑位示意圖
此處收錄首領戰跑位示意圖，要點乃以文字、符號描繪地圖與跑位示意，文字與符號皆應採用全形，以免因客戶端字型不同而產生排版錯位。此處巨集每行前方應自行加入發佈頻道：- /rw：團隊警告
- /ra：團隊
- /y：大喊
- /g：公會
- /s：聊天
- /p：小隊
- /e：表情
980216：納克薩瑪斯．傀儡區．泰迪斯（暱稱電男、電王、電人、泰迪熊）
↙←←逆時針跑位←←↖
正 負
正正正 泰迪熊 負負負
正 負
↘→→逆時針跑位→→↗
980311：納克薩瑪斯．瘟疫區．『不潔者』海根（暱稱：跳舞王、DDR王）
｜ 臺 ｜
一 ｜ 子 ｜ 四
區 ／￣￣｜￣￣＼ 區
／ 二 ｜ 三 ＼
／ 區 ｜ 區 ＼
職業專用
此處收錄針對職業特化的巨集，若為一般僅修改技能名則能通用的巨集，則不收。
戰士
980216：一鍵衝鋒、英勇打擊，外加詭異的釣魚
#showtooltip [equipped:魚竿]釣魚;[stance:1]衝鋒;英勇打擊
/施放 [equipped:魚竿]釣魚;[nocombat,stance:1,target=mouseover,harm][nocombat,stance:1]衝鋒;[nocombat,nostance:1]戰鬥姿態;[combat,nostance:3]狂暴姿態;英勇打擊
若裝備釣竿則施放釣魚；
若不符前項，且不在戰鬥中，且處於戰鬥姿態，且游標對象為敵對，則對游標對象施放衝鋒；
若無游標對象，且不在戰鬥中，且處於戰鬥姿態，則對目標施放衝鋒；
若不符前項，且不處於戰鬥姿態，則施放戰鬥姿態；
若不符前項，且處於戰鬥中，且不處於狂暴姿態，則施放狂暴姿態；
否則，英勇打擊。
聽起來複雜，簡單說，這個巨集會讓你在戰鬥中時切狂姿施放英勇打擊，不在戰鬥中時切戰姿施放衝鋒，裝備魚竿時施放釣魚，狂戰武戰皆適用，建議放在快捷鍵「1」。超級懶人專用。
980216：一鍵衝鋒、阻擾、攔截
#showtooltip [stance:1]衝鋒;[stance:2]阻擾;攔截
/施放 [nocombat,stance:1,target=mouseover,harm][nocombat,stance:1,harm]衝鋒;[stance:2,target=mouseover,exists][stance:2]阻擾;[combat,nostance:3]狂暴姿態;[stance:3,target=mouseover,harm][stance:3,harm]攔截
若不在戰鬥中，且處於戰鬥姿態，且游標對象為敵對，則對游標對象施放衝鋒；
若無游標對象，且不在戰鬥中，且處於戰鬥姿態，則對目標施放衝鋒；
若不符前項，且處於防禦姿態，且游標對象存在，則對游標對象施放阻擾；
若不符前項，且處於防禦姿態，則以一般方式施放阻擾；
若不符前項，且處於戰鬥中，且不處於狂暴姿態，則施放狂暴姿態；
若不符前項，且處於狂暴姿態，且游標對象為敵對，則對游標對象施放攔截；
若不符前項，且處於狂暴姿態，且目標為敵對，則對目標施放攔截。
簡單講，戰姿放衝鋒，防姿放阻擾，狂姿放攔截，而在戰鬥中且不處於狂姿，則切換為狂姿。
980216：一鍵換盾，施放法術反射、盾牆
#showtooltip 法術反射
/停止施法
/裝備 盾牌名稱
/施放 [stance:3]防禦姿態;[equipped:盾牌]法術反射
一鍵換裝並切換至防禦姿態，第二下施放法術反射，通常用在玩家對戰時。
#showtooltip 盾牆
/停止施法
/裝備 盾牌名稱
/施放 [nostance:2]防禦姿態;[equipped:盾牌]盾牆
與法術反射相同，通常用在玩家對戰，以及狂戰仇恨過量被毆的時候。
上面是雙持狂戰專用，由於本來就是雙持，不用更換主手武器，至於拿雙手武器的武戰則必須先將雙手武器換下才能裝上盾牌，巨集如後：
#showtooltip 法術反射
/停止施法
/裝備欄位 16 單手武器名稱
/裝備欄位 17 盾牌名稱
/施放 [stance:3]防禦姿態;[equipped:盾牌]法術反射
#showtooltip 盾牆
/停止施法
/裝備欄位 16 單手武器名稱
/裝備欄位 17 盾牌名稱
/施放 [nostance:2]防禦姿態;[equipped:盾牌]盾牆
後面是依天賦合併版。
#showtooltip 法術反射
/停止施法
/裝備欄位 [spec:2]16 單手武器名稱
/裝備欄位 17 盾牌名稱
/施放 [stance:3]防禦姿態;[equipped:盾牌]法術反射
#showtooltip 盾牆
/停止施法
/裝備欄位 [spec:2]16 單手武器名稱
/裝備欄位 17 盾牌名稱
/施放 [nostance:2]防禦姿態;[equipped:盾牌]盾牆
當中的「spec:2」請修改為你武器天賦的編號，「1」為主天賦，「2」為副天賦（小弟為主狂副武），在武器天賦的情形下，會先裝備雙手武器才換盾，否則直接換盾。盾牆部份會先切換到防禦姿態，按第二下才施放盾牆。法術反射部份，若在狂姿則切換為防姿，按第二下才施放，若不在狂姿則直接施放。
980216：繳械
#showtooltip 繳械
/施放 [stance:2]繳械;防禦姿態
一鍵切換至防禦姿態，第二下施放繳械。
980226：熱血沸騰觸發猛擊
/施放 猛擊
/停止施法
狂戰專用，第一行施放猛擊，第二行中斷施法。啥意思咧？就是避免沒觸發熱血沸騰的時候按下猛擊，浪費唱法時間。如果有觸發熱血沸騰，則猛擊變成瞬發，「/stopcasting」不會造成任何影響，如果沒有觸發熱血沸騰，猛擊需要唱法，則立刻打斷。
980904：換盾、盾擊斷法
#showtooltip 盾擊
/停止施法
/裝備欄位 16 單手武器名稱
/裝備欄位 17 盾牌名稱
/施放 [target=mouseover,harm][target=focus,harm][]盾擊
武戰專用，有游標對象則優先對游標對象施放盾擊，否則對專注目標施放盾擊，否則對目前目標施放盾擊。
980904：換狂姿、拳擊斷法
#showtooltip 拳擊
/停止施法
/施放 [nostance:3]狂暴姿態;[target=mouseover,harm][target=focus,harm][]拳擊
同樣是武戰專用，與前面的盾擊可自行取捨。按第一下切換狂姿，第二下拳擊。優先度同樣是游標對象、專注目標、目標。
聖騎士
980306：祝福合一
#showtooltip
/施放 [mod:alt,btn:2]強效力量祝福;[mod:alt]力量祝福;[mod:ctrl,btn:2]強效智慧祝福;[mod:ctrl]智慧祝福;[mod:shift,btn:2]強效王者祝福;[mod:shift]王者祝福;[btn:2]強效庇護祝福;庇護祝福
Alt：力量祝福
Ctrl：智慧祝福
Shift：王者祝福
無輔助鍵：庇護祝福
左鍵為單體祝福，右鍵為強效祝福。
可自行調整按鍵判斷或技能名稱以符合自己的習慣。
感謝板友launcelot提供。（原文12樓）
980326：聖盾爐石
/連續施法 reset=12 聖盾術,爐石
聖騎士的招牌巨集，第一下聖盾，第二下爐石。
980728：聖盾、神性犧牲
/連續施法 reset=combat/target/10 聖盾術,神性犧牲
第一下放聖盾，第二下放神性犧牲。重置條件只是意思意思，因為這幾個技能的冷卻時間都不算短，刻意去寫準確的重製條件並沒有意義。
980728：聖佑、犧牲聖禦
/施放 聖佑術
/施放 [target=mouseover,help][target=focus,help][help]犧牲聖禦
施放聖佑術，而後：
若游標對象為友好，對游標對象施放犧牲聖禦。
否則，若專注目標為友好，對專注目標施放犧牲聖禦。
否則，若目標為友好，對目標施放犧牲聖禦。
死亡騎士
980324：永恆之眼抓力量火花
/清除目標
/選定指定目標 力量火花
/跑 if(UnitExists("target"))then SetRaidTargetIcon("target", 8)end;
/施放 [harm]死亡之握
/施放 [harm]冰鍊術
/選定指定目標 瑪里苟斯
範圍內有火花則死握冰鍊，並上骷髏圖標，沒有則不執行這部份。
然後選定目標為瑪狗。
跟網路上流通的抓火花巨集不同，此巨集並無使用到專注目標（focus），不會與其他使用專注目標的巨集衝突。
盜賊
980403：一鍵塗毒
/使用 [mod:alt]ALT物品名稱;[mod:ctrl]CTRL物品名稱;[mod:shift]SHIFT物品名稱;無輔助鍵物品名稱
/使用 [button:2]17;16
獵人
980223：強化追蹤
/跑 local t=UnitCreatureType("target");if(t=="不死族")then CastSpellByName("追蹤不死生物") else CastSpellByName("追蹤"..t) end;
若目標為不死族，則施放追蹤不死生物，否則施放「追蹤XX」，「XX」為單位類型。用上了已被封鎖的CastSpellByName……不知道為啥可以用。= =
感謝板友kevinlii提供。（原文8樓）
980920：餵食寵物、復活寵物、召喚寵物、治療寵物合一
/施放 [btn:2]餵養寵物;[target=pet,dead]復活寵物;[nopet]召喚寵物;治療寵物
/使用 [btn:2]食物名稱
右鍵餵食，寵物死亡時復活，寵物不存在時召喚，其餘狀況治療。
/施放 [btn:2,pet]餵養寵物;[target=pet,dead]復活寵物;[nopet]召喚寵物;治療寵物
/關閉巨集 [nobtn:2]
/使用 [pet:寵物一類型]寵物一食物名稱;[pet:寵物二類型]寵物二食物名稱;[pet:寵物三類型]寵物三食物名稱
多寵多食物版本，比如可以讓龍鷹吃甲食物，讓豹吃乙食物等等，只要255字塞得下，可以自行添加。
補充獵人的
------------------------------------------------------------------------------------------------------------------
射擊循環巨集:
#showtooltip 爆裂射擊(),
/cast !擊殺射擊
/castsequence reset=target !爆裂射擊(),毒蛇釘刺(),穩固射擊(),穩固射擊(),!爆裂射擊(),!多重射擊(),穩固射擊(),穩固射擊(),!爆裂射擊(),穩固射擊(),穩固射擊(),!多重射擊(),
/cast !擊殺命令
我的加速等級445攻速2.08使用這個巨集不會有卡gcd的情況.
爆裂射擊可能會比用手動的少放幾箭.
使用此巨集最起碼可以發揮自身能力應有的95%輸出
建議循環還不是非常熟練的人使用
------------------------------------------------------------------------------------------------------------------
施放獵人印記同時判斷並轉換追蹤目標類型巨集:
#showtooltip 獵人印記(),
/script t=UnitCreatureType("target");if t=="不死族" then CastSpellByName("追蹤不死生物");else CastSpellByName("追蹤"..UnitCreatureType('target').."");end;
/cast 獵人印記(),
------------------------------------------------------------------------------------------------------------------
餵寵物巨集:
/cast 餵養寵物
/use 蜜烤馴鹿肉
use後面的物品請自行更改
------------------------------------------------------------------------------------------------------------------
一鍵裸體巨集:
/script k={18,16,17,5,7,1,3,8,10,6,9};j=1;for i=1,4 do for g=1,GetContainerNumSlots(i) do if(not GetContainerItemInfo(i,g))then PickupInventoryItem(k[j]);PutItemInBag(19+i);j=j+1;end;end;end;for i=j,11 do PickupInventoryItem(k[i]);PutItemInBackpack();end;
這不是獵人專用...凡是溜鳥同好皆可使用
通用便捷治療巨集
/施放 [modifier:alt,target=player][target=mouseover,help,nodead,group][help,group][target=targettarget,help,group][target=mouseover,exists,nodead,nogroup][nogroup]技能名稱
自動判定可補可打的技能
/施放 [modifier:alt,target=player][target=mouseover,help,nodead][help][target=targettarget,help][target=player]技能名稱
祝福施放
雙巨集-SHIFT切換巨集，左鍵強效, 右鍵一般
#showtooltip [modifier:SHIFT]強效力量祝福;強效智慧祝福
/施放 [modifier:SHIFT,button:1]強效力量祝福;[modifier:SHIFT]力量祝福;[button:1]強效智慧祝福;智慧祝福
#showtooltip [modifier:SHIFT] 強效王者祝福;強效庇護祝福
/施放 [modifier:SHIFT,button:1]強效王者祝福;[modifier:SHIFT]王者祝福;[button:1]強效庇護祝福;庇護祝福
單巨集-四種祝福-八種施放
#show [modifier:ALT]力量祝福;[modifier:CTRL]智慧祝福;[modifier:SHIFT] 王者祝福;庇護祝福
/施放 [modifier:ALT,button:1]強效力量祝福;[modifier:ALT]力量祝福;[modifier:CTRL,button:1]強效智慧祝福;[modifier:CTRL]智慧祝福;[modifier:SHIFT,button:1];強效王者祝福;[modifier:SHIFT]王者祝福;[button:1]強效庇護祝福;庇護祝福
淨化術
右鍵解自己，左鍵依序判斷：1.目標(友善)，2.對目標(非友善)的目標(友善)，3.無目標時對自己施放
打蜘蛛王ST或MT狂點這巨集都可以第一時間解MT的毒
#showtooltip 淨化術
/跑 SetCVar("Sound_EnableSFX","0")
/施放 [target=player,button:2] [target=target,help][target=targettarget,help][target=player] 淨化術;
/跑 SetCVar("Sound_EnableSFX","1")
右鍵對 自己施放，並且啟動提示訊息。
左鍵對 1.滑鼠的友善目標 2.友善目標 3.不符合以上狀況則對自己施放(無提示訊息)
#showtooltip 崇聖護盾
/施放 [target=player,button:2][target=mouseover,help,exists,nodead][help][target=player]崇聖護盾
/stopmacro [button:1]
/e 對自己施放重聖護盾。
/in 27 /e 崇聖護盾即將消失！
#showtooltip [equipped:魚竿]釣魚;攻擊
/cast [equipped:魚竿] 釣魚
/stopmacro [equipped:魚竿]
/cleartarget [dead]
/dismount [harm]
/startattack
/petattack
----------------------------------------------
同上.但這是拿來甩魔杖的.請點兩下才會甩魔杖
#showtooltip [equipped:魚竿]釣魚;[harm]射擊;攻擊
/cast [equipped:魚竿] 釣魚
/stopmacro [equipped:魚竿]
/cleartarget [dead]
/dismount [harm]
/cast [harm] 射擊;攻擊
/petattack
----------------------------------------------
單體目標用.對你的目標/或是你選擇坦克後打坦克的目標.當你沒目標/目標已死.自動鎖定附近的人(火球術等)
#showtooltip
/cleartarget [dead]
/cast [target=target,harm][target=targettarget,harm] 單體技能
/stopmacro [target=target,harm][target=targettarget,harm]
/startattack
/cast 單體技能
----------------------------------------------
這是引導技能(吸取生命等)
#showtooltip
/stopmacro [channeling]
/cast [target=target,harm,nodead][target=targettarget,harm,nodead] 引導技能
/stopmacro [target=target,harm,nodead][target=targettarget,harm,nodead]
/cleartarget [dead]
/startattack
/cast 引導技能
----------------------------------------------
補血用.補你的滑鼠目標/你的目標/你的目標的目標/你自己
(照順序.哪個成立就優先執行哪個)
#showtooltip 技能
/cast [target=mouseover,help][help][target=targettarget,help][target=player] 技能
ex:
我看著王.補王正在打的那個人
我看著坦.滑鼠移到我的獵人隊友.會先補獵人隊友
我沒有目標.滑鼠移到我的獵人隊友.會先補獵人隊友
我沒目標.滑鼠也沒目標.會補我自己
----------------------------------------------
隱藏/顯示遊戲錯誤 左鍵是隱藏,右鍵是顯示
/script UIErrorsFrame:Show()
/stopmacro [button:2]
/script UIErrorsFrame:Hide()
----------------------------------------------
當你在地球.用地面坐騎
當你在火星/北極.用天空坐騎
當你在地球並按右鍵時.使用技能
當你在火星/北極並按右鍵時.用地面坐騎
在沒辦法用坐騎時.使用技能(室內.游泳.戰鬥等)
#showtooltip [modifier:shift][combat][indoors][harm,nodead]技能;[noflyable]地面;[flyable]天空
/cast [noflyable,button:2][combat][indoors][harm,nodead]技能;[flyable,button:2][noflyable]地面;[flyable]天空
----------------------------------------------
薩滿專用
----------------------------------------------
平常上風怒武器.按shift上火舌武器.按ctrl上大地生命武器.按alt上冰封武器
#showtooltip
/cast [modifier:shift]火舌武器;[modifier:ctrl]大地生命武器;[modifier:alt]冰封武器;風怒武器
/use 16
/控制臺 SET scriptErrors 0
/click StaticPopup1Button1
/控制臺 SET scriptErrors 1
----------------------------------------------
左鍵施放薩滿之怒/精通元素(大絕)
右鍵施放嗜血術
然後不管你按哪個鍵都會放血性狂暴(這是獸人的種族特長)+第1個裝飾品
然後按著shift顯示血性狂暴(種族特長).按著ctrl顯示嗜血術.按著alt顯示復生效果.如果拿盾牌/副手武器顯示精通元素.雙持顯示薩滿之怒.以上全部不成立(像是你空手)顯示血性狂暴(種族特長)
> 這是獸人薩專用.食人妖可以把加速替換掉血性狂暴(種族特長)
#showtooltip [modifier:shift]血性狂暴(種族特長);[modifier:ctrl]嗜血術;[modifier:alt]復生效果;[equipped:盾牌/副手物品]精通元素;[noequipped:盾牌]薩滿之怒;血性狂暴(種族特長)
/cast [button:1] 薩滿之怒
/cast [button:1] 精通元素
/cast 血性狂暴(種族特長)
/use 13
/stopmacro [button:1]
/cast 嗜血術
/y 嗜血術!
然後這是全薩滿通用的
#showtooltip [modifier:ctrl]嗜血術;[modifier:alt]復生效果;[equipped:盾牌/副手物品]精通元素;[noequipped:盾牌]薩滿之怒;嗜血術
/cast [button:1] 薩滿之怒
/cast [button:1] 精通元素
/use 13
/stopmacro [button:1]
/cast 嗜血術
/y 嗜血術!
----------------------------------------------
獵人
----------------------------------------------
沒寵物時召喚寵物
右鍵點擊/寵物死掉時復活寵物
戰鬥時治療寵物.平常餵養寵物.平常右鍵治療寵物
然後食物放在第一個背包的最後一個位子
按著shift樣子會變成復活寵物
#showtooltip [modifier:shift]復活寵物;[nopet]召喚寵物;[pet,combat][modifier:ctrl]治療寵物;餵養寵物
/cast [nopet]召喚寵物;[button:2,nopet][target=pet,dead]復活寵物
/stopmacro [nopet]
/cast [combat]治療寵物;[button:2]治療寵物
/stopmacro [combat]
/cast [nocombat]餵養寵物
/use [button:1] 0 16
----------------------------------------------
如果你帶貓科寵物
常常會在登入遊戲時自己隱身+開畏縮
左鍵點擊自動全部取消
如果要開啟右鍵點擊
然後他現行時點一下會隱身
#showtooltip 潛行
/petautocastoff 潛行
/petautocastoff 畏縮
/petautocaston [button:2] 潛行
/petautocaston [button:2] 畏縮
/cast 潛行
3.3的更新PATCH內容有提到
巨集內的『target』目標判斷字串可以使用『@』代替
比如說
/cast [@=@@ help,@=@,@=player] 聖光閃現
以舊的寫法就會變成
/cast [target=targettarget help,target=target,target=player] 聖光閃現
- "@"符號現在可取代"target="。範例: "/cast [@focus] Flash Heal"。
- 新增巨集條件: "vehicleui"(玩家必須有載具的使用者介面)與"unithasvehicleui"(巨集的目標必須有載具的使用者介面)。
第一項的意思是說，現有巨集的「target=某某」都可以直接取代成「@某某」，取「施放（使用）於某某」之意。這除了能減少打字時間外，也能縮減巨集佔用的字數，以往部份就多了個「target=」結果被255限定住的巨集，現在也可以使用。當然，這類巨集並不多。
例如精華區的「通用對敵施放」（92字）：
/施放 [target=mouseover,harm][target=mouseovertarget,harm][harm][target=targettarget,harm]技能名稱
改寫後（74字）：
/施放 [@mouseover,harm][@mouseovertarget,harm][harm][@targettarget,harm]技能名稱
「vehicleui」、「unithasvehicleui」，前者為自身，後者為目標，在有載具列時為真。比如在戰車內、在操作火砲等等。
例：
/施放 [vehicleui]防空火箭;英勇打擊
自身有載具列時施放防空火箭，否則施放英勇打擊。
/施放 [unithasvehicleui]致死打擊;斷筋
目標有載具列時施放致死打擊，否則施放斷筋。（斷筋對載具無效）
/施放 [@focus,unithasvehicleui]致死打擊;斷筋
兩項更新合用的範例，專注目標有載具列時施放致死打擊，否則施放斷筋。
01-16-28%5D.JPG)
Coin Casino Review 2021 | Exclusive $500 Bonus + 100 Free Spins
回覆刪除Coin Casino is a trusted brand which 카지노 also operates some of the best casinos in the world, septcasino while other gaming sites such 인카지노 as Betfair,